REM LED Tape PACMAN
USECLASS WS2812B
USEVAR LED,LED_NUM,PACMAN,MONSTAR,PCOOKIE
LED_NUM=144:REM The number of LED
PCOOKIE=29:REM Position of Power Cookie
LED=NEW(WS2812B,LED_NUM,0)

DO
 PACMAN=-4
 MONSTAR=PACMAN-5
 T=0
 WHILE PACMAN<PCOOKIE
  REM Clear LEDs
  FOR I=0 TO PCOOKIE
   LED.SETLED(I,0,0,0)
  NEXT

  REM Power Cookie
  U=T AND 7
  IF U>4 THEN U=8-U
  U=U<<4
  LED.SETLED(PCOOKIE,U,U,0)

  REM Cookie
  FOR I=1 TO PCOOKIE-1 STEP 4
   IF I>PACMAN THEN LED.SETLED(I,5,5,0)
  NEXT

  REM PACMAN
  U=T AND 3
  IF U>2 THEN U=4-U
  U=U<<4
  IF PACMAN>=0 THEN LED.SETLED(PACMAN  , U, U,0)
  IF PACMAN>=1 THEN LED.SETLED(PACMAN-1,64,64,0)

  IF T AND 1 THEN
   REM AKABEI
   IF MONSTAR>=0 THEN LED.SETLED(MONSTAR  ,80,0,0)
   IF MONSTAR>=1 THEN LED.SETLED(MONSTAR-1,20,0,0)

   REM PINKY
   IF MONSTAR>=3 THEN LED.SETLED(MONSTAR-3,64,0,40)
   IF MONSTAR>=4 THEN LED.SETLED(MONSTAR-4, 8,0, 5)

   REM AOSUKE
   IF MONSTAR>=6 THEN LED.SETLED(MONSTAR-6,0,64,64)
   IF MONSTAR>=7 THEN LED.SETLED(MONSTAR-7,0, 8, 8)

   REM GUZUTA
   IF MONSTAR>=9  THEN LED.SETLED(MONSTAR-9 ,64,24,16)
   IF MONSTAR>=10 THEN LED.SETLED(MONSTAR-10, 8, 3, 2)

  ELSE
   REM AKABEI
   IF MONSTAR>=0 THEN LED.SETLED(MONSTAR  ,20,0,0)
   IF MONSTAR>=1 THEN LED.SETLED(MONSTAR-1,80,0,0)

   REM PINKY
   IF MONSTAR>=3 THEN LED.SETLED(MONSTAR-3, 8,0, 5)
   IF MONSTAR>=4 THEN LED.SETLED(MONSTAR-4,64,0,40)

   REM AOSUKE
   IF MONSTAR>=6 THEN LED.SETLED(MONSTAR-6,0, 8, 8)
   IF MONSTAR>=7 THEN LED.SETLED(MONSTAR-7,0,64,64)

   REM GUZUTA
   IF MONSTAR>=9  THEN LED.SETLED(MONSTAR-9 , 8, 3, 2)
   IF MONSTAR>=10 THEN LED.SETLED(MONSTAR-10,64,24,16)
  ENDIF

  LED.PUTLED()
  DELAYMS 100
  PACMAN=PACMAN+1
  MONSTAR=MONSTAR+1
  T=T+1
 WEND

 WHILE PACMAN>=0
  REM Clear LEDs
  FOR I=0 TO PCOOKIE
   LED.SETLED(I,0,0,0)
  NEXT

  REM PACMAN
  U=T AND 3
  IF U>2 THEN U=4-U
  U=U<<4
  IF PACMAN>=0 THEN LED.SETLED(PACMAN  ,64,64,0)
  IF PACMAN>=1 THEN LED.SETLED(PACMAN-1, U, U,0)

  REM IJIKE
  IF MONSTAR<PACMAN THEN
   IF MONSTAR>=0  THEN LED.SETLED(MONSTAR  ,0,0,80)
   IF MONSTAR>=1  THEN LED.SETLED(MONSTAR-1,0,0,80)
  ENDIF
  IF MONSTAR-3<PACMAN THEN
   IF MONSTAR>=3  THEN LED.SETLED(MONSTAR-3,0,0,80)
   IF MONSTAR>=4  THEN LED.SETLED(MONSTAR-4,0,0,80)
  ENDIF
  IF MONSTAR-6<PACMAN THEN
   IF MONSTAR>=6  THEN LED.SETLED(MONSTAR-6,0,0,80)
   IF MONSTAR>=7  THEN LED.SETLED(MONSTAR-7,0,0,80)
  ENDIF
  IF MONSTAR-9<PACMAN THEN
   IF MONSTAR>=9  THEN LED.SETLED(MONSTAR-9 ,0,0,80)
   IF MONSTAR>=10 THEN LED.SETLED(MONSTAR-10,0,0,80)
  ENDIF

  LED.PUTLED()
  IF (T AND 1) AND (PACMAN=MONSTAR OR PACMAN=MONSTAR-3 OR PACMAN=MONSTAR-6 OR PACMAN=MONSTAR-9) THEN
   DELAYMS 500
  ELSE
   DELAYMS 100
  ENDIF
  PACMAN=PACMAN-1
  MONSTAR=MONSTAR-(T AND 1)
  T=T+1
 WEND
LOOP