サーバ接続時にログを自動保存するマクロ

本ページではサーバ接続時にログを自動保存するマクロを紹介します。

本マクロの用途

サーバ接続時に、操作ログを自動保存するだけのマクロになります。
画面から「ログを保存する」をクリックしてログ名を打つという動作も、積み重なるとわずらわしいものです。本マクロは、そんな単純動作から作業者を解放してくれます。

また、本マクロの動作完了後にマクロコードを追加することで、指定のサーバにて指定のコマンドを発行するマクロを新たに生成することが可能です。

本マクロの仕様

踏み台(入り口)サーバに指定のユーザでログイン後、指定したサーバにssh接続でログインし、操作ログをD:¥temp¥work¥ttmacro¥ttlog¥yyyymmdd_hhmmss.txtに保存します。

本マクロの注意事項

特にありません。

マクロの配置やログの出力先、仕様などのその他共通注意事項は当サイトで扱うtera termマクロの共通ルールをご確認下さい。

コード

;#################################################################
;接続先指定ログイン
;作成日:yyyymmdd
;作成者:wildfish
;更新日:yyyymmdd
;更新者:wildfish
;説明:サーバ接続時に、操作ログを自動保存するだけのマクロになります。
;踏み台(入り口)サーバに指定のユーザでログイン後、
;指定したサーバにssh接続でログインし、
;操作ログを以下ディレクトリに保存します。
;D:¥temp¥work¥ttmacro¥ttlog¥yyyymmdd_hhmmss.txt
;#################################################################

;#################################################################
;ログイン、接続処理
;#################################################################

username = 'ユーザ名';←踏み台サーバのログインするユーザ名を記入します
hostname = 'ホスト名';←踏み台サーバのホスト名またはIPを記入します

msg = 'passwordを入力'
passwordbox msg 'Get password'
Password = inputstr

msg = hostname
strconcat msg ':22 /ssh /auth=password /user='
strconcat msg username
strconcat msg ' /passwd='
strconcat msg Password

connect msg

settitle"接続先指定ログイン"

;#################################################################
;操作ログの自動保存処理
;#################################################################

getdate datestr
strcopy datestr 1 4 yearstr
strcopy datestr 6 2 monthstr
strcopy datestr 9 2 daystr
gettime timestr
strcopy timestr 1 2 hourstr
strcopy timestr 4 2 minutestr
strcopy timestr 7 2 secondstr

filename = 'D:¥temp¥work¥ttlog¥'
strconcat filename yearstr
strconcat filename monthstr
strconcat filename daystr
strconcat filename '_'
strconcat filename hourstr
strconcat filename minutestr
strconcat filename secondstr
strconcat filename '.txt'

logopen filename 0 0

wait ' ~]$';←一般ユーザのwaitです。rootの場合' ~]#'を指定します。

;#################################################################
;作業担当者出力
;#################################################################
inputbox '作業者名を半角英小文字で入力' '作業担当者名入力画面'
Sagyotan = inputstr
echotan = 'echo '
strconcat echotan Sagyotan
sendln echotan
wait ' ~]$'
;#################################################################
;作業担当者出力終了
;#################################################################


;#################################################################
;接続先指定部
;#################################################################

inputbox '接続先ホスト名' '接続先ホスト名入力画面'
Rmthost = inputstr

sshcmd ='ssh '
strconcat sshcmd username
strconcat sshcmd '@'
strconcat sshcmd Rmthost
sendln sshcmd
wait 'password:'
sendln Password
wait ' ~]$'

;#################################################################
;接続先指定部終了
;#################################################################

tera term macroリスト

メニュー

ページのトップへ戻る